home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / bowling.arc / CREATE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1985-07-12  |  4.0 KB  |  131 lines
  1. 10  REM CREATE LEAGUE RECORDS        (CREATE)
  2. 12  REM Developed by William W. Klaproth,  Moraga Ca.  94556    September 1982
  3. 20  REM MASTER FILE DESCRIPTIONS FOR ALL BOWLING PROGRAMS
  4. 30  OPEN "B:TEAMS.HDR" AS #1 LEN = 64
  5. 40  FIELD #1, 2 AS TM$, 30 AS NAM$, 2 AS RCNT$, 2 AS GAM$, 4 AS PINS$, 2 AS AVG$, 2 AS HIG$, 2 AS HIS$, 4 AS PTSW$, 4 AS PTSL$, 2 AS B1ID$, 2 AS B2ID$, 2 AS B3ID$, 2 AS B4ID$, 2 AS B5ID$
  6. 50  FIELD #1, 2 AS HDRID$, 30 AS LEAGUE$, 2 AS WEEKS$, 2 AS TEAMS$, 4 AS FILLER$, 2 AS BWLPERTM$, 2 AS NXTID$, 2 AS HCPBASE$, 4 AS HCPPCNT$
  7. 60  OPEN "B:BOWLERS.HDR" AS #2 LEN = 64
  8. 70  FIELD #2, 2 AS BBO$, 30 AS BNAM$, 2 AS BRCNT$, 2 AS BGAM$, 4 AS BPINS$, 2 AS BAVG$, 2 AS BHIG$, 2 AS BHIS$, 2 AS BHCP$, 2 AS BHIGH$, 2 AS BHISH$, 2 AS BTM$,2 AS GAM2$, 2 AS SER5$, 2 AS SER6$,2 AS CURSER$,2 AS AVGLSTYR$
  9. 80  OPEN "B:TEAM.DET" AS #3 LEN = 16
  10. 90  FIELD #3,2 AS DTM$, 2 AS TMO$, 2 AS TDAY$, 2 AS TG1$, 2 AS TG2$, 2 AS TG3$, 2 AS TSER$, 2 AS DPTSW$
  11. 100  OPEN "B:BOWLER.DET" AS #4 LEN = 16
  12. 110  FIELD #4,2 AS DBO$, 2 AS BMO$, 2 AS BDAY$, 2 AS BG1$, 2 AS BG2$, 2 AS BG3$, 2 AS BSER$
  13. 120  DIM BNUM%(5)
  14. 130  BID% = 1
  15. 140  CLS
  16. 150  PRINT "LEAGUE INITIALIZATION PROGRAM"
  17. 160  PRINT " "
  18. 170  PRINT "ENTER LEAGUE HEADER DATA"
  19. 180  INPUT "NAME OF LEAGUE:";LNAM$
  20. 190  INPUT "NO OF WEEKS:";IWK%
  21. 200  INPUT "NO OF TEAMS:";ITM%
  22. 210  INPUT "BOWLERS PER TEAM:";IBO%
  23. 220  INPUT "HANDICAP BASE AVERAGE:";IHB%
  24. 230  INPUT "HANDICAP PERCENTAGE:";IPCT
  25. 240  PRINT "LEAGUE NAME:";LNAM$
  26. 250  PRINT "WEEKS  TEAMS  BOWLERS/TM"
  27. 260  PRINT USING "   ##  ";IWK%,ITM%,IBO%
  28. 270  PRINT "HANDICAP BASED ON";IPCT;"% OF";IHB%
  29. 280  INPUT "HAS DATA BEEN ENTERED CORRECTLY? Y/N:";ANS$
  30. 290  IF ANS$ = "Y" GOTO 330
  31. 300  IF ANS$ = "y" GOTO 330
  32. 310  CLS
  33. 320  GOTO 130
  34. 330  FOR T% = 1 TO ITM%
  35. 340  CLS
  36. 350  PRINT "ENTER DATA FOR TEAM NO:";T%
  37. 360  INPUT "TEAM NAME:";TNAM$
  38. 370  LSET NAM$ = TNAM$
  39. 380  RSET RCNT$ = MKI$(0)
  40. 390  RSET GAM$ = MKI$(0)
  41. 400  RSET PINS$ = MKS$(0)
  42. 410  RSET AVG$ = MKI$(0)
  43. 420  RSET HIG$ = MKI$(0)
  44. 430  RSET HIS$ = MKI$(0)
  45. 440  RSET PTSW$ = MKS$(0)
  46. 450  RSET PTSL$ = MKS$(0)
  47. 460  RSET TM$ = MKI$(T%)
  48. 470  FOR B% = 1 TO IBO%
  49. 480  PRINT "BOWLER NO:";B%
  50. 490  INPUT "BOWLER NAME:";INAM$
  51. 500  INPUT "ENTER AVERAGE LAST YEAR:";IAVGLSTYR%
  52. 510  LSET BNAM$ = INAM$
  53. 520  RSET BRCNT$ = MKI$(0)
  54. 530  RSET BGAM$ = MKI$(0)
  55. 540  RSET BPINS$ = MKS$(0)
  56. 550  RSET BAVG$ = MKI$(0)
  57. 560  RSET BHIG$ = MKI$(0)
  58. 570  RSET BHIS$ = MKI$(0)
  59. 580  RSET BHCP$ = MKI$(0)
  60. 590  RSET BHIGH$ = MKI$(0)
  61. 600  RSET BHISH$ = MKI$(0)
  62. 610  RSET BTM$ = MKI$(T%)
  63. 620  RSET GAM2$ = MKI$(0)
  64. 630  RSET SER5$ = MKI$(0)
  65. 640  RSET SER6$ = MKI$(0)
  66. 650  RSET CURSER$ = MKI$(0)
  67. 660  RSET AVGLSTYR$ = MKI$(IAVGLSTYR%)
  68. 670  RSET BBO$ = MKI$(BID%)
  69. 680  PUT #2,BID%
  70. 690  BNUM%(B%) = BID%
  71. 700  BID% = BID% + 1
  72. 710  NEXT B%
  73. 720  RSET B1ID$ = MKI$(BNUM%(1))
  74. 730  RSET B2ID$ = MKI$(BNUM%(2))
  75. 740  RSET B3ID$ = MKI$(BNUM%(3))
  76. 750  RSET B4ID$ = MKI$(BNUM%(4))
  77. 760  RSET B5ID$ = MKI$(BNUM%(5))
  78. 770  RECNO% = T% +1
  79. 780  PUT #1, RECNO%
  80. 790  NEXT T%
  81. 800  CLS
  82. 810  PRINT "SUBSTITUTE NO:";BID%
  83. 820  PRINT "Enter sub name and telephone number (align telephone number under mask.         To quit, enter *END in first four positions of name."
  84. 830  PRINT "            ....................(TEL-XXXX)"
  85. 840  INPUT "BOWLER NAME:",INAM$
  86. 850  IF LEFT$(INAM$,4) = "*END" OR LEFT$(INAM$,4) = "*end" GOTO 1070
  87. 860  INPUT "ENTER AVERAGE LAST YEAR:";IAVGLSTYR%
  88. 870  LSET BNAM$ = INAM$
  89. 880  RSET BRCNT$ = MKI$(0)
  90. 890  RSET BGAM$ = MKI$(0)
  91. 900  RSET BPINS$ = MKS$(0)
  92. 910  RSET BAVG$ = MKI$(0)
  93. 920  RSET BHIG$ = MKI$(0)
  94. 930  RSET BHIS$ = MKI$(0)
  95. 940  RSET BHCP$ = MKI$(0)
  96. 950  RSET BHIGH$ = MKI$(0)
  97. 960  RSET BHISH$ = MKI$(0)
  98. 970  RSET BTM$ = MKI$(0)
  99. 980  RSET GAM2$ = MKI$(0)
  100. 990  RSET SER5$ = MKI$(0)
  101. 1000  RSET SER6$ = MKI$(0)
  102. 1010  RSET CURSER$ = MKI$(0)
  103. 1020  RSET AVGLSTYR$ = MKI$(IAVGLSTYR%)
  104. 1030  RSET BBO$ = MKI$(BID%)
  105. 1040  PUT #2,BID%
  106. 1050  BID% = BID% + 1
  107. 1060  GOTO 800
  108. 1070  LSET LEAGUE$ = LNAM$
  109. 1080  RSET HDRID$ = MKI$(0)
  110. 1090  RSET WEEKS$ = MKI$(IWK%)
  111. 1100  RSET TEAMS$ = MKI$(ITM%)
  112. 1110  RSET BWLPERTM$ = MKI$(IBO%)
  113. 1120  RSET NXTID$ = MKI$(BID%)
  114. 1130  RSET HCPBASE$ = MKI$(IHB%)
  115. 1140  RSET HCPPCNT$ = MKS$(IPCT)
  116. 1150  PUT #1,1
  117. 1160  PRINT "LEAGUE INITIALIZED FOR"; ITM%; " TEAMS, "; IBO%; " BOWLERS PER TEAM"
  118. 1170  PRINT "NEXT AVAILABLE BOWLER ID IS:";BID%
  119. 1180  PRINT "Initializing Team DETAIL file - Please standby . . "
  120. 1190  FOR T% = 1 TO (T% * 50 + 100)
  121. 1200  RSET DTM$ = MKI$(0)
  122. 1210  PUT #3,T%
  123. 1220  NEXT T%
  124. 1230  FOR B% = 1 TO (BID% * 50 + 100)
  125. 1240  RSET DBO$ = MKI$(0)
  126. 1250  PUT #4,B%
  127. 1260  NEXT B%
  128. 1270  PRINT "Processing Completed - Returning to MENU"
  129. 1280  CLOSE
  130. 1290  RUN "A:MENU"
  131.